Arduino Leonardo - Serratura elettronica

Posto su 2020-06-22

Ottenere il codice dall'input dell'utente

Quindi, come ho descritto nella parte 1, dobbiamo ottenere tutti gli input richiesti dall'utente e controllare il codice con quello salvato.

E controlla anche se il display non trabocca. Questo è gestito da questo codice.

GetCode function

const unsigned char MaxPasscodeLength = 19;
unsigned char PasscodeLength;
char Data[MaxPasscodeLength];
char Master[MaxPasscodeLength];

unsigned char data_count = 0;
char Key;

void GetCode() {							// This piece of code handles getting the code from the user
   if (data_count < MaxPasscodeLength) {
    Data[data_count] = Key; 
    lcd.setCursor(data_count,1); 
    lcd.print("*");
    if (EnableDebug) {
      Serial.println();
      Serial.print("Data_count: ");
      Serial.println(data_count);
      Serial.print("Data: ");
      Serial.println(Data[data_count]);
    }
    data_count++;
   }
   else {
      lcd.setCursor(data_count,1);
      lcd.print("*");
      lcd.setCursor(0, 3);
      lcd.print("Passcode Overflow");
      if (EnableDebug) {
        Serial.println();
        Serial.println("Passcode Overflow Error");
      }
      _delay_ms(1000);
      lcd.clear();
      clearData();
   }
}

Controllo del codice

Dobbiamo anche controllare se il codice corrisponde al codice salvato, così sappiamo quando siamo in grado di aprire il lucchetto e quando no.

CheckCode Function

void CodeCorrect() {
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Correct");
  LockState = true;
  _delay_ms(1000);
  if (EnableDebug) {
    Serial.println();
    Serial.println("Opened");
  }
}

void CodeIncorrect() {
  lcd.clear();
  lcd.setCursor(0,0);
  lcd.print("Incorrect");
  if (EnableDebug) {
    Serial.println();
    Serial.println("Incorrect PSWD");
  }
  LockState = false;
  _delay_ms(1000);
}

void OpenLock() {
  if (EnableServo) {
    Lock.write(90);
  }
  lcd.setCursor(0,0);
  lcd.print("Lock Opened");
  lcd.setCursor(0,2);
  lcd.print("Press -* to lock");
  if (EnablePasscodeChange) {
    lcd.setCursor(3,3);
    lcd.print("-# to change code");
  }
  TimeLastActivity = millis();
}

void CloseLock() {
  if (EnableServo) {
    Lock.write(180);
  }
  LockState = false;
  lcd.clear();
  if (EnableDebug) {
    Serial.println();
    Serial.println("Closing");
  }
  TimeLastActivity = millis();
}

void CheckCode() {
  if(data_count == PasscodeLength){
      Data[PasscodeLength] = 0;
      _delay_ms(500);
      lcd.clear();
      if (EnableDebug) {
        Serial.println();
        Serial.print("Data:   ");
        Serial.println(Data);
        Serial.print("Master: ");
        Serial.println(Master);
      }
      if(!strcmp(Data, Master)){
          CodeCorrect();
        }

      else{
          if (EnableDebug) {
            Serial.println();
            Serial.print("PasscodeLength: ");
            Serial.println(PasscodeLength);
            Serial.print("DataCount: ");
            Serial.println(data_count);
          }
          CodeIncorrect();
        }
  }
  else {
      if (EnableDebug) {
        Serial.println();
        Serial.print("Data:   ");
        Serial.println(Data);
        Serial.print("Master: ");
        Serial.println(Master);
        Serial.println();
        Serial.print("PasscodeLength: ");
        Serial.println(PasscodeLength);
        Serial.print("DataCount: ");
        Serial.println(data_count);
      }
      CodeIncorrect();
    }
  lcd.clear();
  clearData();
}

Pagina precedente 7. Il codice - parte 2 - Il display LCD Pagina corrente 8. Il codice - parte 3 - Il codice Pagina successiva 9. Il codice - parte 4 - Altri codici 1. introduzione 2. Lo Schema 3. La tastiera 4. Il modulo LCD 5. Il servo 6. Il codice - parte 1 - La tastiera 7. Il codice - parte 2 - Il display LCD 8. Il codice - parte 3 - Il codice 9. Il codice - parte 4 - Altri codici 10. Il codice - parte 5 - Setup e Loop 11. Il codice completo Pubblicato da Sander Speetjens

Arduino Leonardo - Serratura elettronica

Ottenere il codice dall'input dell'utente

GetCode function

Controllo del codice

CheckCode Function

Commenti