Arduino Leonardo - Serratura elettronica

Posto su 2020-06-22

Guasto al codice nella memoria EEPROM

Ora possiamo ottenere un codice, controllarlo ma che ne dici di salvarlo. Perché quando resetti Arduino la RAM viene cancellata, quindi dobbiamo trovare un altro modo per memorizzarla e poterla modificare senza dover ricaricare il programma. È qui che entra in gioco la EEPROM ...

Quindi dobbiamo usare la libreria EEPROM.

Storing and Getting the code from EEPROM

#include <EEPROM.h>

unsigned char Eeprom_PasscodeLength = 0;

void GetEepromCode() {
   EEPROM.get(0, Eeprom_PasscodeLength);
   if (Eeprom_PasscodeLength) {
      NewPasscodeLength = Eeprom_PasscodeLength;
      for (unsigned char i = 0; i < Eeprom_PasscodeLength; i++) {
        EEPROM.get(i + 1, Master[i]);
      }
   }
   else {
    NewPasscodeLength = PasscodeLength;
    return;
   }
   PasscodeLength = NewPasscodeLength;
}

void WriteEepromCode(){
  EEPROM.put(0, PasscodeLength);
  for (unsigned char i = 0; i < PasscodeLength; i++) {
    EEPROM.put(i + 1, Master[i]);
  }
}

Quindi ora siamo in grado di memorizzare e ottenere un codice dalla EEPROM, è il momento di abilitarlo per modificare il codice mentre il programma è ancora in esecuzione su Arduino .

Changing the code while the program is running

void CheckNewCode() {
  if (EnableDebug) {
    Serial.print("dataCountBuff1: ");
    Serial.println(dataCountBuff1);
    Serial.print("dataCountBuff2: ");
    Serial.println(dataCountBuff2);
    Serial.print("codeBuff1: ");
    Serial.println(code_buff1);
    Serial.print("codeBuff2: ");
    Serial.println(code_buff2);
  }  
  if (dataCountBuff1 == dataCountBuff2) {
      if(!strcmp(code_buff1, code_buff2)){
          NewPasscodeLength = dataCountBuff2;
          for (unsigned char i = 0; i <= MaxPasscodeLength; i++) {
            Master[i] = 0;
          }
          
          for (unsigned char i = 0; i <= NewPasscodeLength; i++) {
            Master[i] = code_buff1[i];
          }

          if (EnableDebug) {
            Serial.println();
            Serial.print("Master: ");
            Serial.println(Master);
          }
          lcd.clear();
          lcd.print("Passcodes Match");
          _delay_ms(1000);
          lcd.clear();
        }
     else {
        NewPasscodeLength = PasscodeLength;
        lcd.clear();
        lcd.setCursor(0,0);
        lcd.print("Codes do not match");
        if (EnableDebug) {
          Serial.println();
          Serial.println("Passcodes do not match");
        }
        _delay_ms(1000);
        lcd.clear();
     }
  }
  else {
    NewPasscodeLength = PasscodeLength;
    lcd.clear();
    lcd.setCursor(0,0);
    lcd.print("Codes do not match");
    if (EnableDebug) {
      Serial.println();
      Serial.println("Passcodes are not the same length");
    }
    _delay_ms(1000);
    lcd.clear();
  }
  clearData();
}

void ChangeCode() {
    dataCountBuff1 = 0;
    dataCountBuff2 = 0;
    for (unsigned char i = 0; i <= MaxPasscodeLength; i++) {
      code_buff1[i] = 0;
      code_buff2[i] = 0;
    }
    if (EnableDebug) {
      Serial.println();
      Serial.println("Changing Master");
    }
    lcd.clear();
    lcd.print("Enter new code:");
    lcd.setCursor(0,2);
    lcd.print("press * to confirm");
    Key = WaitForKey();
    while(Key != '*') {
      GetCode();
      Key = WaitForKey();
    }
    Data[data_count] = 0;
    dataCountBuff1 = data_count;
    for (unsigned char i =0; i <= data_count; i++) {
      code_buff1[i] = Data[i];
    }
    clearData();
    lcd.clear();
    _delay_ms(500);
    lcd.print("Confirm new code:");
    lcd.setCursor(0,2);
    lcd.print("press * to confirm");
    Key = WaitForKey();
    while (Key != '*') {
      GetCode();
      Key = WaitForKey();
    }
    Data[data_count] = 0;
    dataCountBuff2 = data_count;
    for (unsigned char i =0; i <= data_count; i++) {
      code_buff2[i] = Data[i];
    }
    clearData();
    CheckNewCode();
    PasscodeLength = NewPasscodeLength;
    if (EnableDebug) {
      Serial.print("PasscodeLength: ");
      Serial.println(PasscodeLength);
    }
    WriteEepromCode();
}

Pagina precedente 8. Il codice - parte 3 - Il codice Pagina corrente 9. Il codice - parte 4 - Altri codici Pagina successiva 10. Il codice - parte 5 - Setup e Loop 1. introduzione 2. Lo Schema 3. La tastiera 4. Il modulo LCD 5. Il servo 6. Il codice - parte 1 - La tastiera 7. Il codice - parte 2 - Il display LCD 8. Il codice - parte 3 - Il codice 9. Il codice - parte 4 - Altri codici 10. Il codice - parte 5 - Setup e Loop 11. Il codice completo Pubblicato da Sander Speetjens

Arduino Leonardo - Serratura elettronica

Guasto al codice nella memoria EEPROM

Storing and Getting the code from EEPROM

Changing the code while the program is running

Commenti