Sempre puntuale con i moduli orologio in tempo REAL DS1307 e DS3231

Posto su 2016-07-16

Moduli orologio in tempo REAL

Versioni orologio in tempo REAL

La serie di orologi in tempo REAL contiene molti numeri di tipo diversi, tutti con funzionalità comparabili. In questa serie solo 2 versioni sono 'mainstream', vale a dire la DS1307 e il DS3231. Entrambi questi chip hanno la possibilità di collegare una batteria e hanno un pin di uscita sqw, con il quale il controller può ricevere un impulso di clock di (1Hz, 1.024kHz, 4.096kHz, 8.192kHz). Entrambi i circuiti integrati hanno anche un'interfaccia One-Wire, che consente di collegarli tramite I²rivolgersi a C.

Modulo orologio in tempo reale DS1302 - SPIIl modulo orologio in tempo reale DS1302 ha un'interfaccia SPI attraverso la quale può leggere l'ora. Esaurito € 1,90

Modulo orologio in tempo REAL DS3231Modulo orologio in tempo REAL con chip DS3231. Questo modulo garantisce che Arduino conosca sempre l'ora esatta. Collegando Arduino al pin 'sqw' è possibile generare ogni secondo un interrupt con il quale è possibile indirizzare i valori del sensore o un display. disponibile € 4,00

Collegamento del modulo RTC ad Arduino UNO

I moduli RTC sono disponibili in diverse forme e dimensioni, ma la connessione ad Arduino è la stessa per tutti i moduli. Il modulo deve essere comunque alimentato a 5V, inoltre l'interfaccia I2C dovrà essere collegata ai pin SDA (Serial data) SCL (Serial clock) di Arduino (questi sono i pin A4 e A5 di Arduino UNO). Inoltre, l'uscita SQW può essere collegata a qualsiasi pin di Arduino per ricevere un impulso di clock dall'RTC.

Connessione DS1307 Arduino UNO

Codice aC

I valori numerici nei chip RTC sono memorizzati in formato BCD. Il codice BCD è più facile da usare rispetto ai numeri decimali a livello hardware, ma questi codici non sono molto utili nel software. I numeri da e verso il chip devono quindi essere codificati e decodificati in modo che il controller e l'RTC si capiscano.

// Convert decimal to BCD
byte decToBcd(byte val)
{
  return( (val/10*16) + (val%10) );
}
//Convert BCD to decimal
byte bcdToDec(byte val)
{
  return( (val/16*10) + (val%16) );
}

Scrivere l'ora corrente nell'RTC

L'ora deve essere scritta solo una volta sull'RTC quando è collegato alla batteria. L'RTC stesso tiene il tempo e continua a contare, anche quando non è collegato al controller.

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setDS3231time(
    byte second, 
    byte minute, 
    byte hour, 
    byte dayOfWeek, 
    byte dayOfMonth, 
    byte month, 
    byte year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //set next input to start at the seconds register
  Wire.write(0); 
  
  //set seconds
  Wire.write(decToBcd(second)); 
  //set minutes
  Wire.write(decToBcd(minute)); 
  //set hours
  Wire.write(decToBcd(hour)); 
  //set day of week (1=Sunday, 7=Saturday)
  Wire.write(decToBcd(dayOfWeek));  
  //set date (1 to 31)
  Wire.write(decToBcd(dayOfMonth)); 
  //set month
  Wire.write(decToBcd(month));
  //set year 20(0 to 99)
  Wire.write(decToBcd(year)); 
    
  Wire.endTransmission();
}

Orologio del disco rigido

De tijd van de RTC lezen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void readDS3231time(
    byte *second,
	byte *minute,
	byte *hour,
	byte *dayOfWeek,
	byte *dayOfMonth,
	byte *month,
	byte *year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  //set DS3231 register pointer to 00h
  Wire.write(0); 
  Wire.endTransmission();
      
  //request seven bytes of data from DS3231
  Wire.requestFrom(DS3231_I2C_ADDRESS, 7);
  *second = bcdToDec(Wire.read() & 0x7f);
  *minute = bcdToDec(Wire.read());
  *hour = bcdToDec(Wire.read() & 0x3f);
  *dayOfWeek = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month = bcdToDec(Wire.read());
  *year = bcdToDec(Wire.read());
}

Mostra l'ora

Con queste funzioni insieme, il tempo può essere determinato da Arduino . Con la funzione sottostante questi dati vengono scritti sul monitor seriale, ma le possibilità di visualizzare l'ora sono infinite.

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  //set the initial time (only once, not every startup)
  //seconds, minutes, hours, dayofweek, day, month, year
  //11:00:00, Saturday, 2016-07-16
  setDS3231time(00,00,11,7,16,7,16);
}

void displayTime()
{
  byte second, minute, hour; 
  byte dayOfWeek, dayOfMonth, month, year;
  
  //retrieve data
  readDS3231time(&second, &minute, &hour, &dayOfWeek, 				     &dayOfMonth, &month, &year);
    
  //Hour
  Serial.print(hour, DEC);
  Serial.print(":");
  //Minute (+0 if needed)
  if (minute<10)
  {
    Serial.print("0");
  }
  Serial.print(minute, DEC);
  Serial.print(":");
  //Second (+0 if needed)
  if (second<10)
  {
    Serial.print("0");
  }
  Serial.print(second, DEC);
  Serial.print(" ");
    
  //Day
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  //Month
  Serial.print(month, DEC);
  Serial.print("/");
  //Year
  Serial.print(year, DEC);
}


void loop()
{
  displayTime(); 
  delay(1000);
}

SQW frequentie instellen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //move pointer to SQW address
  Wire.write(0x07); 
 
  //set output clock speed
  //0x00 = Off
  //0x10 = 1Hz
  //0x11 = 4.096Hz
  //0x12 = 8.192Hz
  //0x13 = 32.768Hz
  Wire.write(0x10);
 
  Wire.endTransmission();  
}

Con questo codice si può costruire un orologio completo, che può visualizzare l'ora. Questo può essere fatto su un display a 7 segmenti, come un orologio analogico, con segnali di fumo o può anche essere pronunciato quando richiesto. Inoltre l'orario è utilizzabile anche in domotica/domotica, la caffettiera si accende alle 8 del mattino, il microonde alle 17.15 la sera e le tende chiudono alle 19.01:05. Tutto è possibile.

Pubblicato da Robin Blok Sito web Sono interessato all'elettronica, alla programmazione e soprattutto alla loro combinazione. Per Opencircuit scrivo blog in cui spiego come funzionano l'elettronica e i moduli.