Arduino Uno come tester 74HC4051 (MUX/DEMUX).

Posto su 2019-10-04

Test 74HC4051

Il 74HC4051 è un IC multiplexer/demultiplexer. Per verificarlo, Arduino Uno può essere utilizzato con due circuiti integrati 74HC4051. Il primo IC funge da multiplexer, il secondo da demultiplexer.

piedinatura

Spillo	Etichetta	Funzione
1	A4	Canale in entrata/uscita
2	A6	Canale in entrata/uscita
3	A	Ingresso/uscita comune
4	A7	Canale in entrata/uscita
5	A5	Canale in entrata/uscita
6	~E	Abilita (negativo)
7	Bestiame	Alimentazione negativa
8	GND	Terra (0V)
9	Vcc	Alimentazione (5Vdc)
10	A2	Canale in entrata/uscita
11	A1	Canale in entrata/uscita
12	A0	Canale in entrata/uscita
13	A3	Canale in entrata/uscita
14	S0	Riga indirizzo bit 0
15	S1	Riga indirizzo bit 1
16	S2	Riga indirizzo bit 2

Test digitale

Sebbene il 74HC4051 sia un MUX/DEMUX analogico, non può essere testato in analogico con Arduino Uno in quanto non ha uscite analogiche (DAC). Più avanti in questo articolo, viene descritto come ciò può essere ottenuto con una scheda breakout DAC. Per testare digitalmente, sono necessari solo la scheda Arduino e 2 circuiti integrati.

Collegare

Impostare il pin 16 (Vcc) di entrambi i circuiti integrati su 5 V CC; pin 8 (GND) a 0V.

Collegare anche i pin 6 (~E) e 7 (Vee) di entrambi i circuiti integrati a GND.

Collegare i seguenti pin di entrambi i circuiti integrati: 1,2,4,5,15,16,13,12 (A0..A7).

Collegare i pin 11 (S0) di entrambi i circuiti integrati alla scheda Arduino su A0.

Collegare il pin 12 (S1) di entrambi i circuiti integrati alla scheda Arduino su A1.

Collegare i pin 13 (S2) di entrambi i circuiti integrati alla scheda Arduino su A2.

Da IC 1, collega il pin 3 (A) alla scheda Arduino su A4.

Da IC 2, collega il pin 3 (A) alla scheda Arduino su A5.

codice Arduino

Usa il seguente codice per Arduino

Test 74HC4051 MUX/DEMUX met Arduino Uno

/****************************************************************
      Configuratie
****************************************************************/
#define pinS0   A0 // Address select 0
#define pinS1   A1 // Address select 1
#define pinS2   A2 // Address select 2
#define pinA_ic1  A4    // A pin on IC1
#define pinA_ic2  A5    // A pin on IC2
/*****   EINDE CONFIGUTATIE    *****/

// Poll timer
unsigned long lastPoll;

/****************************************************************
      SETUP
****************************************************************/
void setup()
{
  Serial.begin(115200);
  while (!Serial) {
    ; // Wacht op seriele monitor
  }
  Serial.println("--- Seriele monitor gestart ---");

  // Configureer pinnen als uitgangen
  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);
  pinMode(pinA_ic1, OUTPUT);
  // Configureer pinnen als ingangen
  pinMode(pinA_ic2, INPUT);

  lastPoll = millis();
}

/****************************************************************
      LOOP
****************************************************************/
void loop()
{
  static byte byteCounter = 0;
  static bool writeBit;
  static bool readBit;
  String testResult;

  // Genereer willekeurig true of false
  writeBit = bool(random(0, 2));

  // Elke 500ms
  if (millis() - lastPoll >= 500)
  {
    // Selecteer adres
    selectAddress(byteCounter);

    // Schrijf bit naar IC 1
    digitalWrite(pinA_ic1, writeBit);

    // Lees bit van IC 2
    readBit = digitalRead(pinA_ic2);

    if (writeBit == readBit) {
      testResult = " -> OK";
    }
    else {
      testResult = " -> NIET OK";
    }
    

    // In de seriële monitor moet bit schrijf = bit lees
    Serial.print("Op adres " );
    Serial.print(byteCounter, BIN);
    Serial.print(" is schrijf (IC 1) vs lees (IC 2): " );
    Serial.print(writeBit);
    Serial.print(" / ");
    Serial.print(readBit);
    Serial.print(testResult);
    Serial.println();

    // Selecteer volgend adres 
    byteCounter++;
    if (byteCounter > 7) {
      byteCounter = 0;  // Reset counter at 1000 (count 0000 to 0111)
    }
    lastPoll = millis();
  }
}

/****************************************************************
      Zet de Sx pinnen om het gewenste adres te selecteren
****************************************************************/
void selectAddress(byte address) {
  // Lees adres bits
  bool S0 = bool(address >> 0 & 0x01); // Shift rechts en maskeer met 0x01
  bool S1 = bool(address >> 1 & 0x01);
  bool S2 = bool(address >> 2 & 0x01);

  // Zet adres lijnen correct
  digitalWrite(pinS0, S0);
  digitalWrite(pinS1, S1);
  digitalWrite(pinS2, S2);
}
//EINDE

Il risultato è qualcosa di questo genere:

Op adres 0 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 1 / 1 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 0 / 0 -> OK

Componenti

I componenti per questo test:

Elenco dei componenti

74HC4051 Multiplexer - 5 pz Esaurito (venduto per 5) € 3,65 Tagliere 400 punti - bianco Esaurito € 1,95 Maglione Uomo-Maschio set 65 pezzi disponibile € 3,00 Totale € 8,60

Allo stesso modo puoi testare la versione sulla breakout board

SparkFun Multiplexer Breakout - 8 canali (74HC4051)Sblocca tutto il potenziale del 74HC4051 con Sparkfun Multiplexer Breakout. Trasforma quattro pin I/O in otto segnali selezionabili, adatti per una vasta gamma di applicazioni. Facile da usare, affidabile e versatile sia per hobbisti che per professionisti. disponibile € 4,15

Test analogico

Per testare l'analogico è necessario un DAC. L' Arduino Uno non ha questo come standard, ma con l'aiuto della scheda breakout " Adafruit MCP4725 (12bit DAC)", è possibile ottenere questo risultato.

Scheda breakout MCP4725 - DAC a 12 bit con interfaccia I2CIl tuo microcontrollore ha probabilmente un ADC (convertitore analogico -> digitale) ma ha un DAC (convertitore digitale -> analogico)??? Ora può! Questa scheda breakout presenta il DAC a 12 bit MCP4725 di facile utilizzo. Controllalo tramite I2C e inviagli il valore che vuoi che emetta, e il pin VOUT lo avrà. Esaurito € 5,90

Collegare

La connessione deve quindi essere regolata:
Mettere il pin 3 (A) di IC 1 sull'uscita dell'MCP4725 (VOU) (invece che su A5)
Metti il pin 3 (A) di IC 2 sul pin A3 della scheda Arduino (invece che su A4).
I pin A4 (SCA) e A5 (SCL) della scheda Arduino devono essere collegati a SDA e SCL di MCP4725.
Collegare anche VDD e GND della scheda MCP4725 rispettivamente a 5V e GND.
Collegare il pin A0 dell'MCP4725 a GND per selezionare l'indirizzo I2C 0x62.
(Alternativa: selezionare A0 a 5V all'indirizzo 0x63.)

Biblioteche Adafruit

Per controllare il DAC Adafruit MCP4725, si consiglia di scaricare la libreria corrispondente da Adafruit .
Puoi trovarli su Github.

Il codice per il test analogico è quindi il seguente:

Test 74HC4051 MUX/DEMUX met Arduino Uno en DAC

// Voeg MCP4725 DAC bibliotheek toe
#include <Wire.h>               // I2C library
#include >Adafruit_MCP4725.h>   // Adafruit library for MCP4725 (DAC)
Adafruit_MCP4725 dac;

/****************************************************************
      Configuratie
****************************************************************/
#define pinS0   A0 // Address select 0
#define pinS1   A1 // Address select 1
#define pinS2   A2 // Address select 2
#define pinA_ic2  A3    // A pin on IC2
/*****   EINDE CONFIGUTATIE    *****/

// Poll timer
unsigned long lastPoll;

/****************************************************************
      SETUP
****************************************************************/
void setup()
{
  Serial.begin(115200);
  while (!Serial) {
    ; // Wacht op seriele monitor
  }
  Serial.println("--- Seriele monitor gestart ---");

  // Configureer pinnen als uitgangen
  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);

  dac.begin(0x62);  // MCP4725, pin A0 ligt op GND
  // dac.begin(0x63);  // MCP4725, pin A0 ligt op 5V

  lastPoll = millis();
}

/****************************************************************
      LOOP
****************************************************************/
void loop()
{
  static byte byteCounter = 0;
  uint16_t writeChannel; // 12 bit (0-4095)
  uint16_t readChannel;  // 10 bit (0-1023)
  String testResult;

  // Genereer willekeurige analoge uitgang waarde
  writeChannel = random(0, 4096); // random 0-4095 (!)

  // Elke 500ms
  if (millis() - lastPoll >= 500)
  {
    // Selecteer adres
    selectAddress(byteCounter);

    // Schrijf naar DAC
    dac.setVoltage(writeChannel, false);

    // Lees analoge waarde van analoge ingang op Arduino
    readChannel = analogRead(pinA_ic2);

    // Converteer waarden naar volt
    writeChannel = map(writeChannel, 0, 4095, 0, 500);
    readChannel = map(readChannel, 0, 1023, 0, 500);

    // Zijn beide waarden gelijk ?
    if (writeChannel == readChannel) {
      testResult = " -> OK";
    }
    else {
      testResult = " -> NIET OK";
    }

    // In de seriële monitor moet schrijf waarde = lees waarde
    Serial.print("Op adres " );
    Serial.print(byteCounter, BIN);
    Serial.print(" is schrijf (IC 1) vs lees (IC 2): " );
    Serial.print(float(writeChannel)/100);
    Serial.print(" / ");
    Serial.print(float(readChannel)/100);
    Serial.print(testResult);
    Serial.println();

    // Selecteer volgend adres 
    byteCounter++;
    if (byteCounter > 7) {
      byteCounter = 0;  // Reset counter at 1000 (count 0000 to 0111)
    }
    lastPoll = millis();
  }
}

/****************************************************************
      Set the Sx pins to select proper address
****************************************************************/
void selectAddress(byte address) {
  // Lees adres bits
  bool S0 = bool(address >> 0 & 0x01); // Shift rechts en maskeer met 0x01
  bool S1 = bool(address >> 1 & 0x01);
  bool S2 = bool(address >> 2 & 0x01);

  // Zet adres lijnen correct
  digitalWrite(pinS0, S0);
  digitalWrite(pinS1, S1);
  digitalWrite(pinS2, S2);
}
//EINDE

Il risultato sul monitor seriale è di questo genere:

Op adres 10 is schrijf (IC 1) vs lees (IC 2): 3.40 / 3.40 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 4.21 / 4.21 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 0.08 / 0.08 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 1.54 / 1.54 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 1.53 / 1.53 -> OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 4.02 / 4.02 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 0.82 / 0.82 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 0.93 / 0.93 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 3.72 / 3.72 -> OK
Op adres 11 is schrijf (IC 1) vs lees (IC 2): 1.35 / 1.35 -> OK
Op adres 100 is schrijf (IC 1) vs lees (IC 2): 2.64 / 2.64 -> OK
Op adres 101 is schrijf (IC 1) vs lees (IC 2): 1.29 / 1.29 -> OK
Op adres 110 is schrijf (IC 1) vs lees (IC 2): 2.89 / 2.88 -> NIET OK
Op adres 111 is schrijf (IC 1) vs lees (IC 2): 3.54 / 3.54 -> OK
Op adres 0 is schrijf (IC 1) vs lees (IC 2): 4.24 / 4.24 -> OK
Op adres 1 is schrijf (IC 1) vs lees (IC 2): 1.51 / 1.51 -> OK
Op adres 10 is schrijf (IC 1) vs lees (IC 2): 4.20 / 4.20 -> OK

Occasionalmente ci saranno "errori" dovuti ad arrotondamenti e imprecisioni. Ad esempio, puoi vedere che 2,89 V non è uguale a 2,88 V. Tuttavia, in combinazione con tutti gli altri risultati positivi, si può presumere che il MUX/DEMUX funzioni perfettamente.

Pubblicato da Arashi Sito web

Arduino Uno come tester 74HC4051 (MUX/DEMUX).

Test 74HC4051

piedinatura

Test digitale

Collegare

codice Arduino

Test 74HC4051 MUX/DEMUX met Arduino Uno

Componenti

Elenco dei componenti

Test analogico

Collegare

Biblioteche Adafruit

Test 74HC4051 MUX/DEMUX met Arduino Uno en DAC

Commenti