Costruisci il tuo ticker di notizie Bluetooth

Posto su 2017-11-13

Esempio di news ticker

Forniture

Arduino Uno R3 - clone Esaurito O un Arduino Nano € 11,60 MAX7219 4 moduli a matrice di punti Esaurito Questo è il display, te ne serve almeno 1, 2 è ancora meglio! € 10,25 Modulo Bluetooth HC-06 con adattatore - clone disponibile Questo è lo slave Bluetooth HC-06, ti serve 1 € 8,55 Resistore a film metallico 5,6KΩ 1/4W - 100 pezzi Esaurito Il partitore di tensione per il modulo Bluetooth € 1,50 Resistenza a film metallico 10KΩ 1/4W - 10 pezzi disponibile Il partitore di tensione per il modulo Bluetooth € 1,75 Alimentatore Mean Well SGA12E09-P1J - 9V 1,33A disponibile Per una maggiore potenza, USB non può fornire abbastanza € 14,10 Presa DC incorporata 5,5mm x 2,1mm - 5 pezzi disponibile € 2,50 Totale € 50,25

Il programma:

Lo schema mostra come tutto dovrebbe essere collegato. Se hai già una sensazione di rotazione da tutti quei fili, non guardare troppo l'insieme, ma prova a considerare e collegare i moduli uno per uno. Vedrai che non è male.

Lo schema mostra solo un modulo LED quadruplo a matrice di punti, in realtà puoi collegarne due insieme per una doppia larghezza!

Schema di connessione della bacheca

Il modulo bluetooth richiede una piccola attenzione in più. I segnali di comunicazione Bluetooth (TX e RX) funzionano a 3,3 volt, mentre Arduino funziona a 5 volt. I due resistori ridurranno i 5 volt da Arduino a circa 3,3 volt.

La nutrizione:
Puoi vedere che viene utilizzato un alimentatore da 5 volt. Si deve. Un Arduino collegato a USB non può fornire abbastanza corrente per alimentare la matrice LED, soprattutto con una doppia matrice.

Libreria Arduino e Schizzo:

Lo sketch Arduino utilizza due librerie esterne, per installarle cerca MD_MAX72xx nel gestore librerie. Quindi installa MD_Max72xx e MD_Parola

Ticker Libreria Arduino USB

Imposta il modulo giusto:
Dopo aver installato le librerie, dobbiamo dire alla libreria MD_Max72xx quale modulo a matrice di led stiamo usando.

Individua il file sul tuo disco rigido: MD_MAX72xx.h
(probabilmente nella cartella C:\Utenti\tuo nome\Documenti\ Arduino \librerie\MD_MAX72XX\src\)

//Op regel 214, zie je staan:   
#define   USE_PAROLA_HW   1, verander die 1 in 0

//Op regel 237 zie je staan: 
#define   USE_FC16_HW   0,   verander die 0 in 1.

Lo schizzo Arduino :

Quindi ora possiamo caricare lo schizzo.
Copia lo sketch e incolla il codice nel software Arduino , seleziona la porta com corretta e digita Arduino e premi upload!

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>
#include <SoftwareSerial.h>
#include <EEPROM.h>
#define MAX_DEVICES 8
#define CLK_PIN   13
#define DATA_PIN  11
#define CS_PIN    10

// Use softserial for the bluetooth module
SoftwareSerial mySerial(2, 3);

// HARDWARE SPI
MD_Parola LK = MD_Parola(CS_PIN, MAX_DEVICES);

uint8_t scrollSpeed = 30;    // default frame delay value
textEffect_t scrollEffect = PA_SCROLL_LEFT;
textPosition_t scrollAlign = PA_LEFT;
uint16_t scrollPause = 2000; // in milliseconds

// Global message buffers shared by Serial and Scrolling functions
#define  BUF_SIZE  75
char curMessage[BUF_SIZE];
char newMessage[BUF_SIZE];
bool newMessageAvailable = false;

void setup()
{
  // Enable the next line to clear the message from eeprom.
  // EEPROM.write(0,1);
  
  mySerial.begin(9600); 
  delay(500);
  
  // The next line configures the BT-04 (BT-06) Module to NOT report connection status. 
  mySerial.write("\r\nAT+ENABLEIND0\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  // change the name of the BT-04 (BT-06) device, this will not work for HC-06
  mySerial.write("AT+NAMELichtkrant01\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  LK.begin();
  LK.displayClear();
  LK.displaySuspend(false);
  LK.displayText(curMessage, scrollAlign, scrollSpeed, scrollPause, scrollEffect, scrollEffect);  

  // Get the last message from EEPROM
  getMessageFromEeprom();
}


void loop()
{  
  readSerial();
  if (LK.displayAnimate())
  {
    if (newMessageAvailable)
    {
      strcpy(curMessage, newMessage);
      newMessageAvailable = false;
      storeMessageInEeprom();
    }
    LK.displayReset();
  }
}


  
void readSerial(void) {
  static char *cp = newMessage;
  while (mySerial.available())  
  {
    *cp = (char)mySerial.read();
    if ( (*cp == '\r') || (*cp == '\n') || (cp - newMessage >= BUF_SIZE-2)) // end of message character or full buffer
    {
      *cp = '\0'; // end the string   
      cp = newMessage;
      newMessageAvailable = true;
      mySerial.print("Nieuwe Boodschap = ");
      mySerial.println(newMessage);
      ClearRXbuffer();
    }
    else  // move char pointer to next position
      cp++;
  }
}


void storeMessageInEeprom(){
  // Store the message in EEPROM
  EEPROM.write(0,251);
  int i=0;
  char c=curMessage[i];
  while (c !=0){
    EEPROM.write(i+1,c);
    i++;
    c=curMessage[i];
    }
    EEPROM.write(i+1,0);
}

void getMessageFromEeprom(){
  if (EEPROM.read(0)!=251){
    strcpy(curMessage, "Hello! Please Send new message over bluetooth");
    newMessage[0] = '\0';
    } else {      
      int i=0;
      char c = EEPROM.read(i+1);
      while (c!=0){
        curMessage[i++]=c;
        c = EEPROM.read(i+1);
        }
        curMessage[i] = '\0';
        newMessageAvailable=false;         
    }
}

void ClearRXbuffer(){
  while (mySerial.available()){
    char c=mySerial.read(); 
    delay(5);
    } 
}

Se tutto va bene (e perché no?) ora vedrai il messaggio "Ciao, invia un nuovo messaggio tramite bluetooth". Quindi è giunto il momento di installare l'app Android sul telefono e inviare un nuovo messaggio tramite Bluetooth!

L'applicazione per Android:

Per modificare il testo sul news ticker abbiamo bisogno di un programma per terminale Bluetooth, ad esempio il Serial Bluetooth Terminal di Kai Morich, tramite il App Store.

Terminale Bluetooth seriale

Il funzionamento dell'App è abbastanza autoesplicativo, ma nel video lo mostro passo dopo passo.

terminale bluetooth

Attenzione: iOS di Apple non può connettersi al modulo Bluetooth utilizzato, quindi funziona solo con dispositivi Android.

Guarda il video

Ci sono ancora ambiguità? Puoi dare un'occhiata più da vicino a tutto in questo video.

Pubblicato da Bart Venneker Sito web | Youtube Bart Venneker è un appassionato di elettronica e realizza video educativi su elettronica, Arduino e stampanti 3D.

Commenti

Ad Laat

Purtroppo non è possibile trovare le modifiche nella libreria, il che significa che il ticker non funziona, il che è un peccato! Potrebbe essere stata utilizzata una versione diversa? Saluti, Ad de Laat

Posto su 19 novembre 2023

